'
'IntroCAD File Display 
'Richard Wheeldon
'
F$=Fsel$("**")
L=File Length(F$)
Reserve As Work 10,L
Bload F$,Start(10)
S=Start(10)
Screen Open 0,640,200,16,Hires
Curs Off : Flash Off : Paper 1 : Cls 
V=Varptr(F#)
L=Leek(S) : Add S,4
If L<>1234500
   Print "This is not an introCAD File"
   Direct 
End If 
BE=Start(10)+Length(10)
XL#=9.22337 E+18
YL#=9.22337 E+18
XH#=-9.22337 E+18
YH#=-9.22337 E+18
'
While S<BE
   PTS=Peek(S) : Add S,6
   For C=1 To PTS
      VX=Varptr(X#)
      VY=Varptr(Y#)
      Loke VX,Leek(S) : Add S,4
      Loke VY,Leek(S) : Add S,4
      XL#=Min(XL#,X#)
      XH#=Max(XH#,X#)
      YL#=Min(YL#,Y#)
      YH#=Max(YH#,Y#)
   Next 
Wend 
'
S=Start(10)+4
XSCLE#=640.0/(XH#-XL#)
YSCLE#=200.0/(YH#-YL#)
BE=Start(10)+Length(10)
X#=0.0 : Y#=0.0
'XSCLE#=32.0 : YSCLE#=32.0 
Palette $0,$FFF,$800,$CBA,$670,$0,$F00,$90F,$A50,$FF0,$FF,$F7F,$F,$F00,$FDA
Dim PAT(6)
PAT(0)=%1111111111111111
PAT(1)=%1010101010101010
PAT(2)=%1111000011110000
PAT(3)=%1111111111110000
PAT(4)=%1111111111100100
PAT(5)=%1111001100111100
PAT(6)=%1111110000110000
While S<BE
   PTS=Peek(S) : Inc S
   CLR=Peek(S) : Inc S
   TYP=Peek(S) : Inc S
   CNT=Peek(S) : Add S,3
   Set Line PAT(TYP)
   If CLR=15 Then CLR=1
   Ink CLR+1
   For C=1 To PTS
      VX=Varptr(X#)
      VY=Varptr(Y#)
      Loke VX,Leek(S) : Add S,4
      Loke VY,Leek(S) : Add S,4
      X#=X#-XL# : Y#=Y#-YL#
      If C=1
         Plot X#*XSCLE#,199-Y#*YSCLE#
      Else 
         Draw , To X#*XSCLE#,199-Y#*YSCLE#
      End If 
   Next 
Wend